Reflection and introspection

Juliaには、さまざまな実行時リフレクション機能が用意されています。

Module bindings

Moduleの公開名はnames(m::Module)で取得できます。この関数は、公開バインディングを表すSymbol要素の配列を返します。names(m::Module, all = true)は、公開されているかどうかにかかわらず、m内のすべてのバインディングのシンボルを返します。

DataType fields

DataTypeのフィールド名は、fieldnamesで調べられます。たとえば、次の型に対してfieldnames(Point)を実行すると、フィールド名を表すSymbolのタプルが返されます。

julia> struct Point
           x::Int
           y
       end

julia> fieldnames(Point)
(:x, :y)

Pointオブジェクトの各フィールドの型は、Point変数自体のtypesフィールドに格納されています。

julia> Point.types
svec(Int64, Any)

xにはIntという注釈が付いています。一方、型定義ではyに注釈が付いていなかったため、yはデフォルトでAny型になります。

型自体は、DataTypeという構造体で表されます。

julia> typeof(Point)
DataType

fieldnames(DataType)は、DataType自体の各フィールド名を返します。そのフィールドの1つが、上の例で確認したtypesフィールドです。

Subtypes

任意のDataTypeの直接のサブタイプは、subtypesで一覧表示できます。たとえば、抽象型DataTypeであるAbstractFloatには、(具象)サブタイプが4つあります。

julia> InteractiveUtils.subtypes(AbstractFloat)
5-element Vector{Any}:
 BigFloat
 Core.BFloat16
 Float16
 Float32
 Float64

抽象サブタイプもこの一覧に含まれますが、その下位のサブタイプは含まれません。subtypesを再帰的に適用すれば、型ツリー全体を調べられます。

subtypesはInteractiveUtils内にありますが、REPLでは自動的にエクスポートされることに注意してください。

DataType layout

DataTypeの内部表現は、Cコードとの連携において非常に重要です。その詳細を調べるための関数がいくつか用意されています。isbitstype(T::DataType)は、TがC互換のアラインメントで格納されている場合にtrueを返します。fieldoffset(T::DataType, i::Integer)は、型の先頭から見たフィールドiのオフセット(バイト単位)を返します。

Function methods

任意のジェネリック関数のメソッドは、methodsで一覧表示できます。methodswithを使うと、指定した型を受け取るメソッドをメソッドディスパッチテーブルから検索できます。

Expansion and lowering

Metaprogrammingの節で説明したように、macroexpand関数は、指定したマクロの、引用符が付かず補間された式(Expr)形式を返します。macroexpandを使うには、式ブロック自体をquoteしてください(そうしないとマクロが評価され、その結果が渡されてしまいます)。たとえば、次のようになります。

julia> macroexpand(@__MODULE__, :(@invoke identity(1::Int)))
:(Core.invoke(identity, Base.Tuple{Int}, 1))

Base.Meta.show_sexprとdumpは、任意の式をS式形式で表示したり、指定した深さまでネストした詳細を表示したりするために使います。

最後に、Meta.lower関数は、任意の式のlowered形式を返します。代入、分岐、呼び出しなどの言語構文が、どのように基本操作へ対応付けられるかを理解するうえで特に役立ちます。

julia> Meta.lower(@__MODULE__, :( [1+2, sin(0.5)] ))
:($(Expr(:thunk, CodeInfo(
1 ─ %1 = :+
│   %2 =   dynamic (%1)(1, 2)
│   %3 = sin
│   %4 =   dynamic (%3)(0.5)
│   %5 =   dynamic Base.vect(%2, %4)
└──      return %5
))))

Intermediate and compiled representations

関数の低水準化形式を調べるには、表示するメソッドを指定する必要があります。ジェネリック関数には、型シグネチャの異なるメソッドが多数存在する場合があるためです。この目的には、メソッドごとのコード低水準化を行うcode_loweredと、型推論後の形式を表示するcode_typedを使えます。code_warntypeは、code_typedの出力にハイライトを加えます。

さらに機械語に近い段階では、code_llvmを使って関数のLLVM中間表現を出力できます。最終的なコンパイル済み機械語はcode_nativeで取得できます(まだ呼び出されていない関数の場合、JITコンパイル/コード生成が実行されます)。

利便性のため、上記の関数にはマクロ版も用意されています。これらのマクロでは通常の関数呼び出しを渡すと、引数の型が自動的に展開されます。

julia> @code_llvm +(1,1)
;  @ int.jl:87 within `+`
; Function Attrs: sspstrong uwtable
define i64 @"julia_+_476"(i64 signext %0, i64 signext %1) #0 {
top:
  %2 = add i64 %1, %0
  ret i64 %2
}

詳しくは、@code_lowered、@code_typed、@code_warntype、@code_llvm、@code_nativeを参照してください。

Printing of debug information

前述の関数とマクロには、出力するデバッグ情報のレベルを制御するキーワード引数debuginfoがあります。

julia> InteractiveUtils.@code_typed debuginfo=:source +(1,1)
CodeInfo(
    @ int.jl:87 within `+`
1 ─ %1 = intrinsic Base.add_int(x, y)::Int64
└──      return %1
) => Int64

debuginfoに指定できる値は、:none、:source、:defaultです。デフォルトではデバッグ情報は出力されませんが、Base.IRShow.default_debuginfo[] = :sourceを設定すれば変更できます。